76 KiB
Emacs configuration
My configuration for vanilla Emacs
Initial
Let's setup some basics.
Firstly, set full name and mail address for use in a variety of applications, including encryption.
(setq user-full-name "Aryadev Chavali"
user-mail-address "aryadev@aryadevchavali.com")Let's set all yes or no questions to single letter responses.
(fset 'yes-or-no-p 'y-or-n-p)Coding system
Set the encoding to utf-8-unix by default.
(use-package emacs
:straight nil
:init
(setq-default buffer-file-coding-system 'utf-8-unix
save-buffer-coding-system 'utf-8-unix))No littering
Setup no-littering, which cleans up many of the default directories in Emacs.
(straight-use-package 'no-littering)
(setq no-littering-etc-directory (expand-file-name ".config/" user-emacs-directory)
no-littering-var-directory (expand-file-name ".local/" user-emacs-directory))
(require 'no-littering)File saves and custom file
Now let's setup file saving and auto-revert-mode. Along with that, setup the custom-file to exist in the var-directory
(use-package emacs
:straight nil
:init
(setq backup-directory-alist `(("." . ,(no-littering-expand-var-file-name "saves/")))
global-auto-revert-non-file-buffers nil
auto-revert-verbose nil)
(setq custom-file (no-littering-expand-etc-file-name "custom.el"))
:config
(global-auto-revert-mode 1))Hide-show mode
Turn on hs minor mode for all prog-mode.
(use-package hideshow
:straight nil
:hook (prog-mode-hook . hs-minor-mode))Aesthetics
Load my custom "personal-theme" theme (look at this file).
(use-package custom
:demand t
:straight nil
:config
(load-theme 'monokai t))Set font size to 125 if no monitor is plugged in.
(use-package faces
:straight nil
:config
(set-face-attribute 'default nil :height 115))Turn off the startup buffer because I prefer Dashboard, and write into the scratch buffer some nice information about Emacs.
(use-package startup
:straight nil
:defer t
:init
(setq inhibit-startup-screen t
initial-scratch-message (format ";; Emacs v%s\n" emacs-version)
ring-bell-function 'ignore))Turn off blinking-cursor-mode as we will later be setting up hl-line, which does a better job of indicating where the cursor is on screen.
(use-package frame
:straight nil
:config
(blink-cursor-mode 0))Custom Functions
These are custom functions I have defined for various purposes.
New line function
Vim bindings don't have a nice way of adding new lines before or after
the current line while staying in normal mode. You can use o/O to
enter insert mode at a new line, but this isn't the same as being able
to stay in normal mode while opening newlines and only adds extra
keypresses if your only purpose was to open up some lines. As this is
Emacs I can extend it as I wish, so I decided to define a new line
function that won't remove me from normal state.
The logic is pretty simple:
- Record current location as
old - Use the predefined vim functions for opening new lines above and below with insert mode
- Return to
old - Enter normal state
(with-eval-after-load "evil"
(defun dx:newline (&optional BACKWARD)
(interactive)
(save-excursion
(cond ((and BACKWARD (= BACKWARD 1)) (evil-open-below 1))
(t (evil-open-above 1))))
(evil-normal-state)))Toggle buffer
Toggle buffer preamble
There are many cases where 'toggling' a buffer is very useful. For example, toggling a shell to access it quickly and hide it away with little annoyance.
This is negligible with a bit of Emacs lisp. However, as stated earlier, there are many cases where this is useful. Following the DRY principle means a more abstract function would be better to use here.
One may use higher order functions to create an abstract form that handles toggling, and then the caller can wrap this call in a new function if they wish to use it in a keybinding. This format or construct is kinda common (using a higher order function and wrapping it in an interactive function for use in a binding), so I created a macro that further wraps this functionality, creating a custom function for you.
The macro asks for a function name, a buffer name and the function necessary to create a buffer with that name. It then generates a function with the given name that holds the necessary logic to 'toggle' buffers.
Code
(defmacro +dx/create-toggle-function (func-name buf-name buf-create)
"Generate a function named func-name that toggles
the buffer with name buf-name and creation function buf-create."
`(defun ,func-name ()
(interactive)
(let* ((buffer (or (get-buffer ,buf-name) (,buf-create)))
(displayed (get-buffer-window buffer)))
(cond (displayed
(select-window displayed)
(delete-window))
(t
(display-buffer buffer)
(select-window (get-buffer-window buffer)))))))Power function
Basic, tail recursive algorithm for calculating powers.
(defun pow (a n &optional initial)
"Raise a to the nth power. Use initial to set the initial value."
(let ((init (or initial 1)))
(if (= n 0)
init
(pow a (- n 1) (* a init)))))Define procedure
The lambda macro provides a function with possible arguments. A
procedure is a type of form that takes no arguments. This macro
returns an anonymous function with no arguments with all the forms
provided. It returns it in 'backquoted' form as that is the most
common use of this macro.
(defmacro proc (&rest CDR)
"For a given list of forms CDR, return a quoted non-argument lambda."
`(quote (lambda () ,@CDR)))Core packages
General
Setup general, a good package for defining keys. In this case, I
generate a new definer for the "LEADER" keys. Leader is bound to
SPC and it's functionally equivalent to the doom/spacemacs leader.
Local leader is bound to SPC , and it's similar to doom/spacemacs
leader but doesn't try to fully assimilate the local-leader map
instead just picking stuff I think is useful.
(use-package general
:demand t
:config
(general-def
:states '(normal motion)
"SPC" nil
"M-V" #'dx:newline
"M-v" (proc (interactive) (dx:newline 1)))
(general-create-definer leader
:states '(normal motion)
:keymaps 'override
:prefix "SPC")
(general-create-definer local-leader
:states '(normal motion)
:prefix "SPC ,")
(leader
:infix "b"
"d" #'kill-this-buffer))Some default binds in Emacs
With a ton of use-package declarations (to defer until the last moment), bind to general some basic binds.
(use-package face-remap
:straight nil
:general
(general-def
:states '(normal motion)
"C--" #'text-scale-decrease
"C-=" #'text-scale-increase))
(use-package frame
:straight nil
:general
(general-def
"C-x d" #'delete-frame))
(use-package simple
:straight nil
:general
(leader
"SPC" #'execute-extended-command
"u" #'universal-argument
";" #'eval-expression))
(use-package files
:straight nil
:general
(leader
"q" #'save-buffers-kill-terminal
"cF" (proc (interactive) (find-file "~/Code/")))
(leader
:infix "f"
"f" #'find-file
"s" #'save-buffer
"p" (proc (interactive) (find-file (concat user-emacs-directory "config.org")))))
(use-package compile
:straight nil
:general
(leader
"cc" #'compile
"cC" (proc (interactive)
(let ((current-prefix-arg '(1)))
(call-interactively #'compile)))))
(use-package imenu
:straight nil
:general
(leader
"si" #'imenu))
(use-package help
:straight nil
:general
(leader
"h" #'help-command))
(use-package async
:straight nil
:general
(leader
"!" #'async-shell-command))Evil
Evil Preamble
Evil (Emacs VI Layer) is a package that brings the Vi experience to Emacs. Packaged with it by default are:
- The modal system
- EX
- Vi mapping functions
This provides a lot of stuff for the average vim user moving to Emacs. However there are many other packages surrounding evil that port even greater functionality from vi to Emacs. Surround, commenting, multiple cursors and further support to other packages are configured here.
Evil Core
Setup the evil package, with some opinionated keybindings:
- Switch
evil-upcaseandevil-downcasecos I'd rather have the non-capital one be upcase due to how much I use it - Switch
evil-goto-markandevil-goto-mark-lineas I'd rather have the global one closer to the home row
(use-package evil
:hook (after-init-hook . evil-mode)
:general
(general-def
:states '(normal motion)
"TAB" #'evil-jump-item
"r" #'evil-replace-state
"zC" #'hs-hide-level
"'" #'evil-goto-mark
"`" #'evil-goto-mark-line
"gu" #'evil-upcase
"gU" #'evil-downcase)
(general-def
:states 'visual
:keymaps '(emacs-lisp-mode-map lisp-interaction-mode-map)
"gr" #'eval-region)
(leader
"w" #'evil-window-map
"wd" #'delete-frame)
:init
(setq evil-want-keybinding nil
evil-split-window-below t
evil-vsplit-window-right t
evil-want-abbrev-expand-on-insert-exit t)
:config
(fset #'evil-window-vsplit #'make-frame))Evil surround
(use-package evil-surround
:after evil
:config
(global-evil-surround-mode))Evil commentary
(use-package evil-commentary
:after evil
:config
(evil-commentary-mode))Evil mc
Setup for multicursors in Evil mode. Don't let evil-mc setup it's own keymap because it uses 'gr' as its prefix, which I don't like.
Instead, bind some useful functions to my personal dx:evil-mc-map
which is bound to 'gz'. Define a function dx:evil-mc-cursor-here
which pauses cursors upon placing a cursor at the current position.
(use-package evil-mc
:after evil
:bind (("M-p" . evil-mc-skip-and-goto-prev-cursor)
:map dx:evil-mc-map
("q" . evil-mc-undo-all-cursors)
("d" . evil-mc-make-and-goto-next-match)
("j" . evil-mc-make-cursor-move-next-line)
("k" . evil-mc-make-cursor-move-prev-line)
("j" . evil-mc-make-cursor-move-next-line)
("m" . evil-mc-make-all-cursors)
("z" . dx:evil-mc-cursor-here)
("r" . evil-mc-resume-cursors)
("s" . evil-mc-pause-cursors))
:init
(setq evil-mc-key-map nil)
(define-prefix-command 'dx:evil-mc-map)
(bind-key "gz" dx:evil-mc-map evil-normal-state-map)
:config
(global-evil-mc-mode +1)
(defun dx:evil-mc-cursor-here ()
(interactive)
(evil-mc-make-cursor-here)
(evil-mc-pause-cursors)))Evil collection
Setup evil collection, but don't turn on the mode. Instead, I'll turn on setups for specific modes I think benefit from it.
(use-package evil-collection
:after evil
:config
(evil-collection-require 'dired))Completion
Completion Preamble
Emacs is a text based interface. As a text based interface it heavily leverages searches and user filters to manage input and provide functionality. Though the standard model of completion may be desirable to some, it can be advanced through the use of 'completion frameworks'.
These frameworks handle the input from the user for common commands and provide a differing interface to the one Emacs comes with. Most of these completion frameworks provide a text based menu that is actively filtered as more input is provided (progressive input filtering). Along with these frameworks come added functionality and applications to integrate into the Emacs environment further.
One may say that when using a completion framework there is no point in using any other framework as they encompasses so much of the default functionality. This is wrong: I'd argue that with a bit of management and Emacs lisp it's totally possible to pick and mix your options. For small number selections (like finding files) use something like Ido and for something larger like searching buffers use ivy.
Along with frameworks, there is a configuration for the
completions-list, which is actually the original and default method of
completion within Emacs. When you first install Emacs without a
config, any 'completing-read' function leverages the completions-list when
TAB is used.
Though I believe Ido is a better completion system than the completions-list, it still has it's place and can be used in tandem with ido.
Ido
Ido is a very old completion package that still works great to this day. Though it is limited in its scope (and may thus be called a completion add-on rather than a full on framework), it is still a very powerful package. With the use of ido-completing-read+, it may be used similarly to a fully fledged completion framework.
(use-package ido
:demand t
:general
(general-def
:keymaps '(ido-buffer-completion-map
ido-file-completion-map
ido-file-dir-completion-map
ido-common-completion-map)
(kbd "M-j") #'ido-next-match
(kbd "M-k") #'ido-prev-match
(kbd "C-x o") #'evil-window-up)
:init
(setq ido-decorations
(list "{" "}" " \n" " ..." "[" "]" " [No match]" " [Matched]"
" [Not readable]" " [Too big]" " [Confirm]")
completion-styles '(flex partial-completion intials emacs22))
(setq-default ido-enable-flex-matching t
ido-enable-dot-prefix t
ido-enable-regexp nil)
:config
(ido-mode)
(ido-everywhere))Ido-completing-read+
Ido completing-read+ is a package that extends the ido package to work with more text based functions.
(use-package ido-completing-read+
:after ido
:config
(ido-ubiquitous-mode +1))Amx
Amx is a fork of Smex that works to enhance the execute-extended-command interface. It also provides support for ido or ivy (though I'm likely to use ido here) and allows you to switch between them.
It provides a lot of niceties such as presenting the keybind when looking for a command.
(use-package amx
:after ido
:config
(amx-mode))Completions-list
(use-package simple
:straight nil
:general
(general-def
:keymaps 'completion-list-mode-map
:states '(normal motion)
"l" #'next-completion
"h" #'previous-completion
"ESC" #'delete-completion-window
"q" #'quit-window
"RET" #'choose-completion)
:config
(with-eval-after-load "evil"
(setq evil-emacs-state-modes (cl-remove-if
#'(lambda (x) (eq 'completions-list-mode x))
evil-emacs-state-modes))
(add-to-list 'evil-normal-state-modes 'completions-list-mode)))Ivy
Ivy is a completion framework for Emacs, and my preferred (sometimes second favourite) one. It has a great set of features with little to no pain with setting up.
Counsel
Setup for counsel. Load after ivy and helpful.
Along with that, set the help function and variable functions to their helpful counterparts.
(use-package counsel
:commands +org/swiper-goto
:general
(leader
"ss" #'counsel-grep-or-swiper
"sr" #'counsel-rg)
:init
(general-def
[remap describe-bindings] #'counsel-descbinds
[remap load-theme] #'counsel-load-theme)
:config
(setq ivy-initial-inputs-alist nil))Ivy Core
Setup for ivy, in preparation for counsel. Turn on ivy-mode just after init.
Setup vim-like bindings for the minibuffer ("C-(j|k)" for down|up the selection list).
(use-package ivy
:defer 10
:general
(general-def
:keymaps 'ivy-minibuffer-map
"M-j" #'ivy-next-line-or-history
"M-k" #'ivy-previous-line-or-history
"C-c C-e" #'ivy-occur)
(general-def
:keymaps 'ivy-switch-buffer-map
"M-j" #'ivy-next-line-or-history
"M-k" #'ivy-previous-line-or-history)
:config
(require 'counsel nil t)
(setq ivy-height 10
ivy-wrap t
ivy-fixed-height-minibuffer t
ivy-use-virtual-buffers nil
ivy-virtual-abbreviate 'full
ivy-on-del-error-function #'ignore
ivy-use-selectable-prompt t))Counsel etags
Counsel etags allows me to search generated tag files for tags. I already have a function defined to generate the tags, so it's just searching them which I find to be a bit of a hassle, and where this package comes in.
(use-package counsel-etags
:after counsel
:general
(leader "st" #'counsel-etags-find-tag))Company
Company is the auto complete system I use. I don't like having heavy setups for company as it only makes it slower to use. In this case, just setup some evil binds for company.
(use-package company
:hook
(prog-mode-hook . company-mode)
(eshell-mode-hook . company-mode)
:general
(general-def
:states 'insert
(kbd "C-SPC") #'company-complete)
(general-def
:states '(normal insert)
"M-j" #'company-select-next
"M-k" #'company-select-previous))Pretty symbols
Prettify symbols mode allows for users to declare 'symbols' that replace text within certain modes. For example, you may replace the 'for' word in c-mode in trade of the logical symbol for universal quantification. Though this may seem like useless eye candy, it has aided my comprehension and speed of recognition (recognising symbols is easier than words for many, including me).
Now here I provide a macro +pretty/set-alist. This macro works pretty simply: given a mode hook, as well as a list of pairs typed (text to substitute, symbol to replace with). Then I add a hook to the given mode, setting the prettify-symbols-alist to the symbols given.
I've declared it pretty high up into my config so that the rest of my packages can leverage it.
(use-package prog-mode
:straight nil
:init
(setq prettify-symbols-unprettify-at-point t)
:config
(with-eval-after-load "use-package-core"
(add-to-list 'use-package-keywords ':pretty)
(defun use-package-normalize/:pretty (_name-symbol _keyword args)
args)
(defun use-package-handler/:pretty (name _keyword args rest state)
(use-package-concat
(use-package-process-keywords name rest state)
(let ((arg args)
forms)
(while arg
(let* ((carg (car arg))
(mode (car carg))
(rest (cdr carg)))
(add-to-list
'forms
`(add-hook
',mode
(lambda ()
(setq prettify-symbols-alist ',rest)
(prettify-symbols-mode)))))
(setq arg (cdr arg)))
forms))))
(defmacro +pretty/set-alist (mode &rest symbols)
`(add-hook
',mode
(lambda ()
(setq prettify-symbols-alist ',symbols)
(prettify-symbols-mode))))
(defun +pretty/set-alist-f (mode symbols)
`(+pretty/set-alist mode ,@symbols)))Here's a collection of symbols I have currently that may be used later.
("null" . "∅")
("list" . "ℓ")
("string" . "𝕊")
("true" . "⊤")
("false" . "⊥")
("char" . "ℂ")
("int" . "ℤ")
("float" . "ℝ")
("!" . "¬")
("&&" . "∧")
("||" . "∨")
("for" . "∀")
("return" . "⟼")
("print" . "ℙ")
("lambda" . "λ")
Window management
Window management is really important. I find the default window handling of Emacs incredibly annoying: sometimes consuming my windows, sometimes creating new ones. Of course, as Emacs is a powerful lisp interpreter, this is easily manageable.
Here I create a few use-package extensions that manages the whole ordeal of adding a new record to the display-buffer-alist, a useful abstraction that makes it easy to manage the various buffers created by packages.
(use-package window
:straight nil
:defer t
:general
(leader
:infix "b"
"b" #'switch-to-buffer
"K" #'kill-buffer
"j" #'next-buffer
"k" #'previous-buffer)
:init
(with-eval-after-load "use-package-core"
(add-to-list 'use-package-keywords ':display)
(defun use-package-normalize/:display (_name-symbol _keyword args)
args)
(defun use-package-handler/:display (name _keyword args rest state)
(use-package-concat
(use-package-process-keywords name rest state)
(let ((arg args)
forms)
(while arg
(add-to-list 'forms
`(add-to-list 'display-buffer-alist
',(car arg)))
(setq arg (cdr arg)))
forms)))))Setup default display records
Using the :display keyword, setup up some display-buffer-alist
records.
(use-package window
:straight nil
:defer t
:display
("\\*\\(Wo\\)?Man.*"
(display-buffer-at-bottom)
(window-height . 0.25))
("\\*Process List\\*"
(display-buffer-at-bottom)
(window-height . 0.25))
("\\*compilation\\*"
(display-buffer-at-bottom)
(window-height . 0.25))
("\\*\\(Ido \\)?Completions\\*"
(display-buffer-in-side-window)
(window-height . 0.25)
(side . bottom))
("\\*Async Shell Command\\*"
(display-buffer-at-bottom)
(window-height . 0.25)))Auto typing
Auto typing Preamble
Snippets are a system by which pieces of code can be inserted via prefixes. For example, an 'if' snippet would work by first inserting the word 'if' then pressing some expansion key such as TAB. This will insert a set of text that may be have some components that need to be further filled by the user.
The popular solution is Yasnippet. Yasnippet is a great package for snippets, which I use heavily in programming and org-mode. I setup here the global mode for yasnippet and a collection of snippets for ease of use.
However, Emacs provides its own 'auto typing' facilities. Abbrevs and skeletons make up the popular solution within Emacs default. Abbrevs are for simple expressions wherein there is only one user input (say, getting today's time which only requires you asking for it). They provide a lot of inbuilt functionality and are quite useful. Skeletons, on the other hand, are for higher level insertions
Abbrevs
Just define a few abbrevs for various date-time operations. Also define a macro that will assume a function for the expansion, helping with abstracting a few things away.
(use-package abbrev
:straight nil
:hook
(prog-mode-hook . abbrev-mode)
(text-mode-hook . abbrev-mode)
:init
(defmacro +autotyping/deff-abbrev (ABBREV-TABLE ABBREV EXPANSION)
"Wraps around define-abbrev to fill in some repeated stuff
when expansion is a function."
`(define-abbrev
,ABBREV-TABLE
,ABBREV
""
(proc (insert ,EXPANSION))))
:config
(+autotyping/deff-abbrev
global-abbrev-table
"sdte"
(format-time-string "%Y-%m-%d" (current-time)))
(+autotyping/deff-abbrev
global-abbrev-table
"stme"
(format-time-string "%H:%M:%S" (current-time)))
(+autotyping/deff-abbrev
text-mode-abbrev-table
"sday"
(format-time-string "%A" (current-time)))
(+autotyping/deff-abbrev
text-mode-abbrev-table
"smon"
(format-time-string "%B" (current-time))))Skeletons
Defining some basic skeletons and a macro to help generate an abbrev as well.
(use-package skeleton
:straight nil
:after abbrev
:config
(defmacro +autotyping/gen-skeleton-abbrev (mode abbrev &rest skeleton)
(let* ((table (intern (concat (symbol-name mode) "-abbrev-table")))
(skeleton-name (intern (concat "+skeleton/" (symbol-name mode) "/" abbrev))))
`(progn
(define-skeleton
,skeleton-name
""
,@skeleton)
(define-abbrev ,table
,abbrev
""
',skeleton-name)))))Auto insert
(use-package autoinsert
:straight nil
:hook (after-init-hook . auto-insert-mode))Yasnippet default
Setup global mode after evil mode has been loaded
(use-package yasnippet
:after evil
:hook
(prog-mode-hook . yas-minor-mode)
(text-mode-hook . yas-minor-mode)
:general
(leader
"i" #'yas-insert-snippet)
:config
(yas-load-directory (no-littering-expand-etc-file-name "yasnippet/snippets")))Yasnippet snippets
Collection of snippets, activate after yasnippet has been loaded.
(use-package yasnippet-snippets
:after yasnippet)Emacs Mode-line
Firstly, declare a variable for the separator between each module
(defconst +modeline/separator " " "Separator between modules.")Then declare a variable for the number of separators between each module in the modeline.
(defconst +modeline/sep-count 4 "Number of +modline/separator instances separating modules.")Then, declare a list of reserved characters for which the previously declared seperator won't be applied when placed at the end of a module string.
(defconst +modeline/reserved-chars (list "[" "(")
"Characters that, when at the end of a module string, won't have the separator applied to them.")Now declare a function that applies the separator with respect to the reserved characters to any one string.
(defun +modeline/handle-string (STR)
(condition-case nil
(progn
(string-blank-p STR)
(cond ((cl-member (car (last (split-string STR "" t))) +modeline/reserved-chars :test #'string=) STR)
(t (concat STR (cl-reduce #'concat (cl-loop for i from 1 to +modeline/sep-count collect +modeline/separator))))))
(error STR)))Finally, set the mode-line-format.
(setq-default
mode-line-format
(mapcar #'+modeline/handle-string
(list "%l:%c"
"%p["
'(:eval (upcase
(substring
(format "%s" (if (bound-and-true-p evil-state) evil-state ""))
0 1)))
"]"
"%+%b("
'(:eval (format "%s" major-mode))
")"
"%I"
vc-mode
mode-line-end-spaces)))Small packages
ISearch
(use-package isearch
:straight nil
:general
(:keymaps 'isearch-mode-map
"M-s" #'isearch-repeat-forward))Display line numbers
I don't like using this mode by default, but I'd like to configure it if possible. Line numbers are a necessary evil a lot of times, and it's useful for presentations.
(use-package display-line-numbers
:straight nil
:defer t
:commands display-line-numbers-mode
:general
(leader
"tl" #'display-line-numbers-mode)
:init
(setq-default display-line-numbers-type 'relative))Hl-line
Hl-line is a
(use-package hl-line
:hook (text-mode-hook . hl-line-mode))Projectile
Setup projectile, along with the tags command. Also bind "C-c C-p" to the projectile command map for quick access.
(use-package projectile
:after evil
:hook (prog-mode-hook . projectile-mode)
:general
(leader "p" #'projectile-command-map)
:init
(setq projectile-tags-command "ctags -Re -f \"%s\" %s \"%s\"")
:config
(projectile-mode))Counsel projectile
Counsel projectile provides the ivy interface to projectile commands, which is really useful.
(use-package counsel-projectile
:after (projectile counsel)
:config
(counsel-projectile-mode +1))Hydra
Use hydras for stuff that I use often, currently buffer manipulation
(use-package hydra
:after evil
:init
(defun dx:kill-defun ()
"Mark defun then kill it."
(interactive)
(mark-defun)
(delete-active-region t))
(defun dx:paste-section ()
"Paste the current kill-region content above section."
(interactive)
(open-line 1)
(yank))
:config
(defhydra hydra-buffer (evil-normal-state-map "SPC b")
"buffer-hydra"
("l" next-buffer)
("h" previous-buffer)
("c" kill-this-buffer))
(defhydra hydra-goto-chg (evil-normal-state-map "g;")
"goto-chg"
(";" goto-last-change "goto-last-change")
("," goto-last-change-reverse "goto-last-change-reverse"))
(defhydra hydra-code-manipulator (global-map "C-x c")
"code-manip"
("j" evil-forward-section-begin)
("k" evil-backward-section-begin)
("m" mark-defun)
("d" dx:kill-defun)
("p" dx:paste-section)
("TAB" evil-toggle-fold)))Avy
Setup avy with leader. As I use avy-goto-char-timer a lot, use the
C-s bind which replaces isearch. Switch isearch to M-s in case I
need to use it.
(use-package avy
:after evil
:general
(leader
:infix "s"
"l" #'avy-goto-line)
(general-def
:states '(normal motion)
(kbd "C-s") #'avy-goto-char-timer
(kbd "M-s") #'isearch-forward))Ace window
Though evil provides a great many features in terms of window management, much greater than what's easily available in Emacs, ace window can provide some nicer chords for higher management of windows (closing, switching, etc).
(use-package ace-window
:after evil
:custom
(aw-keys '(?a ?s ?d ?f ?g ?h ?j ?k ?l))
:general
(general-def
:states '(normal motion)
[remap evil-window-next] #'ace-window))Helpful
Basic setup, will be fully integrated in counsel.
(use-package helpful
:general
(general-def
[remap describe-function] #'helpful-callable
[remap describe-variable] #'helpful-variable
[remap describe-key] #'helpful-key)
:display
("\\*[Hh]elp.*"
(display-buffer-at-bottom)
(inhibit-duplicate-buffer . t)
(window-height . 0.25))
:config
(evil-define-key 'normal helpful-mode-map "q" #'quit-window))Which-key
Pretty simple, just activate after init.
(use-package which-key
:config
(which-key-mode))Keychord
Keychord is only really here for this one chord I wish to define: "jk" for exiting insert state. Otherwise, I don't really need it.
(use-package key-chord
:after evil
:config
(key-chord-define evil-insert-state-map "jk" #'evil-normal-state)
(key-chord-mode +1))(Rip)grep
Grep is likely one of the most important programs ever invented; a must-have tool for any Linux users inventory. It is a searching utility that allows one to search files for certain regex patterns. The fact that there have been so many attempts to replace grep (with limited success) only goes to show how important its general function is to people.
Ripgrep is a grep-like utility written in Rust. It subsumes not only
the ability to search a given file but also to search multiple files
within a directory (which is usually only done by composing the
program find with grep to search multiple files). It is incredibly
fast by virtue of its regex optimisations and the use of ignore files
such as .gitignore to filter files when searching.
Grep has default Emacs utilities that use a compilation style buffer
to search a variety of differing data sets. grep searches files,
rgrep searches in a directory using the find binary and zgrep
searches archives. This is a great solution for most computer
environments as basically all of them will have grep and find
installed. Even when you ssh into a remote machine, they're likely
to have these tools.
The ripgrep package provides utilities to ripgrep projects and files
for strings via the rg binary. Though ivy comes with counsel-rg
using it makes me dependent on the ivy framework, and this
configuration is intentionally built to be modular and switchable. Of
course, this requires installing the rg binary which is available in
most repositories nowadays.
Grep
(use-package grep
:display
("grep\\*"
(display-buffer-at-bottom)
(window-height . 0.25))
:straight nil
:general
(leader
"sd" #'rgrep))rg
(use-package rg
:commands (+rg/search-in-new-frame)
:general
(leader
"sr" #'rg
"sR" #'+rg/search-in-new-frame)
(:keymaps 'rg-mode-map
"]]" #'rg-next-file
"[[" #'rg-prev-file
"q" #'quit-window)
:init
(setq rg-group-result t
rg-hide-command t
rg-show-columns nil
rg-show-header t
rg-custom-type-aliases nil
rg-default-alias-fallback "all"
rg-buffer-name "*ripgrep*")
:config
(defun +rg/search-in-new-frame ()
(interactive)
(let ((frame (make-frame)))
(select-frame frame)
(call-interactively #'rg))))Applications
Dashboard
Dashboard creates a custom dashboard for Emacs that replaces the initial startup screen in default Emacs.
(use-package dashboard
:straight t
:general
(leader
"ab" (proc (interactive) (switch-to-buffer "*dashboard*")))
:init
(setq initial-buffer-choice (lambda () (get-buffer "*dashboard*"))
dashboard-banner-logo-title "Oreomacs"
dashboard-center-content nil
dashboard-set-init-info t
dashboard-startup-banner (no-littering-expand-etc-file-name "dashboard/logo2.png")
dashboard-set-footer t
dashboard-set-navigator t
dashboard-items '((projects . 5)
(recents . 5)))
:config
(dashboard-setup-startup-hook)
(general-def
:states '(normal motion)
:keymaps 'dashboard-mode-map
"r" #'dashboard-jump-to-recent-files
"p" #'dashboard-jump-to-projects
"}" #'dashboard-next-section
"{" #'dashboard-previous-section))Calendar
Calendar is a simple inbuilt application within Emacs that helps with date functionalities. I add functionality to copy dates from the calendar to the kill ring and bind it to "Y".
(use-package calendar
:straight nil
:defer t
:commands (+calendar/copy-date +calendar/toggle-calendar)
:display
("\\*Calendar\\*"
(display-buffer-at-bottom)
(inhibit-duplicate-buffer . t)
(window-height . 0.17))
:general
(:keymaps 'calendar-mode-map
:states '(normal motion)
"Y" #'+calendar/copy-date)
(leader
"ad" #'+calendar/toggle-calendar)
:config
(defun +calendar/copy-date ()
"Copy date under cursor into kill ring."
(interactive)
(if (use-region-p)
(call-interactively #'kill-ring-save)
(let ((date (calendar-cursor-to-date)))
(when date
(setq date (encode-time 0 0 0 (nth 1 date) (nth 0 date) (nth 2 date)))
(kill-new (format-time-string "%Y-%m-%d" date))))))
(+dx/create-toggle-function +calendar/toggle-calendar "*Calendar*" #'calendar))Mail is a funny thing; most people use it just for business or advertising and it's come out of use in terms of personal communication in the west for the most part (largely due to "social" media applications). However, this isn't true for the open source and free software movement who heavily use mail for communication.
Integrating mail into Emacs helps as I can send source code and integrate it into my workflow just a bit better.
Notmuch
(defconst +mail/signature "---------------\nAryadev Chavali")
(defconst +mail/local-dir (concat user-emacs-directory ".mail/"))
(use-package notmuch
:commands notmuch
:general
(leader "am" #'notmuch)
:init
(defun +mail/sync-mail ()
"Sync mail via mbsync."
(interactive)
(start-process-shell-command "" nil "mbsync -a"))
:custom
(notmuch-show-logo nil)
(notmuch-hello-sections '(notmuch-hello-insert-saved-searches notmuch-hello-insert-alltags))
(mail-signature +mail/signature)
(mail-default-directory +mail/local-dir)
(mail-source-directory +mail/local-dir)
(message-signature +mail/signature)
(message-auto-save-directory +mail/local-dir)
(message-directory +mail/local-dir)
:config
;; sync mail after refresh
(advice-add #'notmuch-poll-and-refresh-this-buffer :before
#'+mail/sync-mail)
(with-eval-after-load "evil-collection"
(evil-collection-notmuch-setup)))Smtpmail
(use-package smtpmail
:after notmuch
:commands mail-send
:custom
(smtpmail-smtp-server "mail.aryadevchavali.com")
(smtpmail-smtp-user "aryadev")
(smtpmail-smtp-service 587)
(smtpmail-stream-type 'starttls)
:init
(setq send-mail-function #'smtpmail-send-it
message-send-mail-function #'smtpmail-send-it))Dired
Setup for dired. Make dired-hide-details-mode the default mode when using dired-mode, as it removes the clutter. Setup evil collection for dired (even though dired doesn't really conflict with evil, there are some corners I'd like to adjust).
(use-package dired
:straight nil
:hook (dired-mode-hook . dired-hide-details-mode)
:init
(setq-default dired-listing-switches "-AFBl --group-directories-first --color")
:general
(leader
:infix "d"
"f" #'find-dired
"D" #'dired-other-frame
"d" #'dired-jump)
:config
(with-eval-after-load "evil-collection"
(evil-collection-dired-setup))
(defun +dired/display-thumb-or-file ()
"If the file under point is a image file then display a
thumb, otherwise open the file."
(interactive)
(let* ((filename (dired-get-filename))
(ext (file-name-extension filename)))
(if (or (string= ext "png")
(string= ext "jpg")
(string= ext "jpeg")
(string= ext "gif"))
(image-dired-display-thumb)
(find-file-other-frame filename))))
(general-def
:states '(normal motion)
:keymaps 'dired-mode-map
"SPC" nil
"SPC ," nil)
(local-leader
:keymaps 'dired-mode-map
"l" #'dired-maybe-insert-subdir
"u" #'dired-undo
"i" #'+dired/display-thumb-or-file))Xwidget
Xwidget is a package (must be compiled at source) which allows for the
insertion of arbitrary xwidgets into Emacs through buffers. One of its
premier uses is in navigating the web which it provides through the
function xwidget-webkit-browse-url. This renders a fully functional
web browser within Emacs.
Though I am not to keen on using Emacs to browse the web via xwidget (EWW does a good job on its own), I am very interested in its capability to render full fledged web pages which include JavaScript, as it may come of use when doing web development. I can see the results of work very quickly without switching windows or workspaces.
Xwidget Core
(use-package xwidget
:straight nil
:display
("\\*xwidget.*"
(display-buffer-pop-up-frame))
:general
(leader "au" #'xwidget-webkit-browse-url)
(general-def
:states '(normal motion)
:keymaps 'xwidget-webkit-mode-map
"q" #'quit-window
"h" #'xwidget-webkit-scroll-backward
"j" #'xwidget-webkit-scroll-up
"k" #'xwidget-webkit-scroll-down
"l" #'xwidget-webkit-scroll-forward
"+" #'xwidget-webkit-zoom-in
"-" #'xwidget-webkit-zoom-out
(kbd "C-f") #'xwidget-webkit-scroll-up
(kbd "C-b") #'xwidget-webkit-scroll-down
"H" #'xwidget-webkit-back
"L" #'xwidget-webkit-forward
"gu" #'xwidget-webkit-browse-url
"gr" #'xwidget-webkit-reload
"gg" #'xwidget-webkit-scroll-top
"G" #'xwidget-webkit-scroll-bottom))Xwidget Extensions
Define a function +xwidget/render-file that reads a file name and
presents it in an xwidget. If the current file is an HTML file, ask
if user wants to open current file. Bind it to aU in the leader.
Also define a function +xwidget/search-query that first asks the
user what search engine they want to use (Duck Duck Go and DevDocs
currently) then asks for a query, which it parses then presents in an
xwidget window. Bind to as in the leader.
(use-package xwidget
:straight nil
:commands (+xwidget/render-file +xwidget/search)
:general
(leader
"aU" #'+xwidget/render-file
"as" #'+xwidget/search)
:config
(defun +xwidget/render-file (&optional FORCE)
"Find file (or use current file) and render in xwidget."
(interactive)
(cond
((and (not FORCE) (or (string= (replace-regexp-in-string ".*.html"
"html" (buffer-name)) "html")
(eq major-mode 'web-mode)
(eq major-mode 'html-mode))) ; If in html file
(if (y-or-n-p "Open current file?: ") ; Maybe they want to open a separate file
(xwidget-webkit-browse-url (format "file://%s" (buffer-file-name)))
(+xwidget/render-file t))) ; recurse and open file via prompt
(t
(xwidget-webkit-browse-url
(format "file://%s" (read-file-name "Enter file to open: "))))))
(defun +xwidget/search ()
"Run a search query on some search engine and display in
xwidget."
(interactive)
(let* ((engine (completing-read "Engine: " '("duckduckgo.com" "devdocs.io") nil t))
(query-raw (read-string "Enter query: "))
(query
(cond
((string= engine "duckduckgo.com") query-raw)
((string= engine "devdocs.io") (concat "_ " query-raw)))))
(xwidget-webkit-browse-url (concat "https://" engine "/?q=" query)))))Eshell
Eshell is the integrated shell environment for Emacs. Though it isn't necessarily the best shell, it really suits the 'integrated computing environment' moniker that Emacs gets.
It may be argued that Emacs integrates within itself many of the
functionalities that one would use within a shell or terminal. Stuff
like compilation, file management, large scale text manipulation could
be done through Emacs' own tools (compile, dired and occur come
to mind). However, I'd argue that eshell's greatest ability comes from
it's separation (or perhaps better phrased, integration) of two
'parsers': the Lisp parser and the Shell parser. With these parsers
you can mix and match at will for use in the shell, which grants
greater power than many shells I know of.
Eshell Core
Setup a function that toggles the eshell window rather than
just opening it via +dx/toggle-buffer.
Along with that setup the prompt so it looks a bit nicer and add
pretty symbols to eshell.
(use-package eshell
:commands +shell/toggle-shell
:display
("\\*e?shell\\*" ; for general shells as well
(display-buffer-at-bottom)
(window-height . 0.25))
:pretty
(eshell-mode-hook
("lambda" . "λ")
("numberp" . "ℤ")
("t" . "𝕋")
("nil" . "∅"))
:general
(leader
"tt" #'+shell/toggle-eshell)
:init
(add-hook
'eshell-mode-hook
(proc
(interactive)
(general-def
:states '(insert normal)
:keymaps 'eshell-mode-map
"M-l" (proc (interactive) (eshell/clear)
"M-j" #'eshell-next-matching-input-from-input
"M-k" #'eshell-previous-matching-input-from-input)
(local-leader
:keymaps 'eshell-mode-map
"c" (proc (interactive) (eshell/clear)
(recenter))
"k" #'eshell-kill-process))))
:config
(setq eshell-cmpl-ignore-case t
eshell-cd-on-directory t
eshell-prompt-function
(proc
(concat
(format "[%s]\n" (abbreviate-file-name (eshell/pwd)))
"λ "))
eshell-prompt-regexp "^λ ")
(+dx/create-toggle-function
+shell/toggle-eshell
"*eshell*"
eshell))Elfeed
Elfeed is the perfect RSS feed reader, integrated into Emacs perfectly. I've got a set of feeds that I use for a large variety of stuff, mostly media and entertainment. I've also bound "<leader> ar" to elfeed for loading the system.
(use-package elfeed
:general
(leader "ar" #'elfeed)
(general-def
:states '(normal motion)
:keymaps 'elfeed-search-mode-map
"gr" #'elfeed-update
"s" #'elfeed-search-live-filter
"<return>" #'elfeed-search-show-entry)
:init
(setq elfeed-db-directory (no-littering-expand-var-file-name "elfeed/"))
(setq +rss/feed-urls
'(("Arch Linux"
"https://www.archlinux.org/feeds/news/"
Linux)
("LEMMiNO"
"https://www.youtube.com/feeds/videos.xml?channel_id=UCRcgy6GzDeccI7dkbbBna3Q"
YouTube Stories)
("The Onion"
"https://www.theonion.com/rss"
Social)
("Dark Sominium"
"https://www.youtube.com/feeds/videos.xml?channel_id=UC_e39rWdkQqo5-LbiLiU10g"
YouTube Stories)
("Dark Sominium Music"
"https://www.youtube.com/feeds/videos.xml?channel_id=UCkLiZ_zLynyNd5fd62hg1Kw"
YouTube Music)
("Nexpo"
"https://www.youtube.com/feeds/videos.xml?channel_id=UCpFFItkfZz1qz5PpHpqzYBw"
YouTube)
("Techquickie"
"https://www.youtube.com/feeds/videos.xml?channel_id=UC0vBXGSyV14uvJ4hECDOl0Q"
YouTube)
("3B1B"
"https://www.youtube.com/feeds/videos.xml?channel_id=UCYO_jab_esuFRV4b17AJtAw"
YouTube)
("Fredrik Knusden"
"https://www.youtube.com/feeds/videos.xml?channel_id=UCbWcXB0PoqOsAvAdfzWMf0w"
YouTube Stories)
("Barely Sociable"
"https://www.youtube.com/feeds/videos.xml?channel_id=UC9PIn6-XuRKZ5HmYeu46AIw"
YouTube Stories)
("Atrocity Guide"
"https://www.youtube.com/feeds/videos.xml?channel_id=UCn8OYopT9e8tng-CGEWzfmw"
YouTube Stories)
("Hacker News"
"http://morss.aryadevchavali.com/news.ycombinator.com/rss"
Social)
("Hacker Factor"
"https://www.hackerfactor.com/blog/index.php?/feeds/index.rss2"
Social)
("BBC Top News"
"http://morss.aryadevchavali.com/feeds.bbci.co.uk/news/rss.xml"
News)
("BBC Tech News"
"http://morss.aryadevchavali.com/feeds.bbci.co.uk/news/technology/rss.xml"
News)))
:config
(with-eval-after-load "evil-collection"
(evil-collection-elfeed-setup))
(setq elfeed-feeds (cl-map 'list #'(lambda (item)
(append (list (nth 1 item)) (cdr (cdr item))))
+rss/feed-urls)))Magit
Magit is the git porcelain for Emacs, which perfectly encapsulates the git cli. In this case, I just need to setup the bindings for it. As magit will definitely load after evil (as it must be run by a binding, and evil will load after init), I can use evil-collection freely. Also, define an auto insert for commit messages so that I don't need to write everything myself.
(use-package magit
:display
("magit:.*"
(display-buffer-same-window)
(inhibit-duplicate-buffer . t))
("magit-diff:.*"
(display-buffer-below-selected))
("magit-log:.*"
(display-buffer-same-window))
:general
(leader "g" #'magit-status)
:init
(setq magit-completing-read-function 'magit-ido-completing-read
vc-follow-symlinks t)
(with-eval-after-load "autoinsert"
(define-auto-insert '("COMMIT_EDITMSG" , "Commit")
'(nil
"(" (read-string "Enter feature/module: ") ")"
(read-string "Enter simple description: ") "\n\n"
_))))
(use-package evil-magit
:after magit
:config
(evil-magit-init))IBuffer
(use-package ibuffer
:general
(leader
"bi" #'ibuffer)
:config
(with-eval-after-load "evil-collection"
(evil-collection-ibuffer-setup)))Proced
Proced is the process manager for Emacs. Just setup evil-collection for it.
(use-package proced
:straight nil
:general
(leader
"ap" #'proced)
:display
("\\*Proced\\*"
(display-buffer-at-bottom)
(window-height . 0.25)))Calculator
Surprise, surprise Emacs comes with a calculator. At this point there is little that surprises me in terms of Emacs' amazing capabilities.
calc-mode is a calculator system within Emacs that provides a
diverse array of mathematical operations. It uses reverse polish
notation to do calculations (though there is a standard infix
algebraic notation mode) and provides incredible utilities.
(use-package calc
:straight nil
:display
("*Calculator*"
(display-buffer-at-bottom)
(window-height . 0.18))
:general
(leader
"ac" #'calc)
:init
(setq calc-algebraic-mode t)
:config
(with-eval-after-load "evil-collection"
(evil-collection-calc-setup)))Calctex
calc-mode also has a 3rd party package called calctex. It renders
mathematical expressions within calc as if they were rendered in TeX.
You can also copy the expressions in their TeX forms, which is pretty
useful when writing a paper. I've set a very specific lock on this
repository as it's got quite a messy work-tree and this commit seems to
work for me given the various TeX utilities installed via Arch.
(use-package calctex
:after calc
:straight (calctex :type git :host github :repo "johnbcoughlin/calctex")
:hook (calc-mode-hook . calctex-mode))Ledger
(use-package ledger-mode
:defer t)
(use-package evil-ledger
:after ledger-mode)Major modes, programming and text
Setups for common major modes and languages.
Text Configuration
Standard packages and configurations for the text-mode. These configurations are usually further placed on
Flyspell
Flyspell allows me to quickly spell check text documents. I use flyspell primarily in org mode, as that is my preferred prose writing software, but I also need it in commit messages and so on. So flyspell-mode should be hooked to text-mode.
(use-package flyspell
:hook (text-mode-hook . flyspell-mode)
:general
(general-def
:states '(normal motion)
:keymaps 'text-mode-map
(kbd "M-a") #'flyspell-correct-word-before-point
(kbd "M-A") #'flyspell-auto-correct-word))White space
Deleting whitespace, highlighting when going beyond the 80th character limit, all good stuff. I don't want to highlight whitespace for general mode categories (Lisp shouldn't really have an 80 character limit), so set it for specific modes need the help.
(use-package whitespace
:straight nil
:general
(general-def
:states '(normal motion)
"M--" #'whitespace-cleanup)
:hook
(before-save-hook . whitespace-cleanup)
(c-mode-hook . whitespace-mode)
(c++-mode-hook . whitespace-mode)
(haskell-mode-hook . whitespace-mode)
(python-mode-hook . whitespace-mode)
:init
(setq whitespace-style '(face lines-tail tabs tab-mark trailing newline)
whitespace-line-column 80))Set auto-fill-mode for all text-modes
Auto fill mode is nice for most text modes, 80 char limit is great.
(add-hook 'text-mode-hook #'auto-fill-mode)Smartparens
Smartparens is a smarter electric-parens, it's much more aware of context and easier to use.
(use-package smartparens
:hook
(prog-mode-hook . smartparens-mode)
(text-mode-hook . smartparens-mode)
:after evil
:config
(setq sp-highlight-pair-overlay nil
sp-highlight-wrap-overlay t
sp-highlight-wrap-tag-overlay t)
(let ((unless-list '(sp-point-before-word-p
sp-point-after-word-p
sp-point-before-same-p)))
(sp-pair "'" nil :unless unless-list)
(sp-pair "\"" nil :unless unless-list))
(sp-local-pair sp-lisp-modes "(" ")" :unless '(:rem sp-point-before-same-p))
(require 'smartparens-config))Show-paren-mode
Show parenthesis for Emacs
(add-hook 'prog-mode-hook #'show-paren-mode)Programming Configuration
Eldoc
Eldoc presents documentation to the user upon placing ones cursor upon any symbol. This is very useful when programming as it:
- presents the arguments of functions while writing calls for them
- presents typing and documentation of variables
(use-package eldoc
:straight nil
:hook (prog-mode-hook . eldoc-mode)
:init
(global-eldoc-mode 1))
(use-package eldoc-box
:hook (eldoc-mode-hook . eldoc-box-hover-mode)
:init
(setq eldoc-box-position-function #'eldoc-box--default-upper-corner-position-function
eldoc-box-clear-with-C-g t))Eglot
Eglot is a library of packages to communicate with LSP servers for better programming capabilities. Interactions with a server provide results to the client, done through JSON.
(use-package eglot
:after project
:defer t
:hook
(c++-mode-hook . eglot-ensure)
(c-mode-hook . eglot-ensure)
(python-mode-hook . eglot-ensure)
:general
(leader
:keymaps 'eglot-mode-map
:infix "c"
"f" #'eglot-format
"a" #'eglot-code-actions
"r" #'eglot-rename
"R" #'eglot-reconnect)
:init
(setq eglot-stay-out-of '(flymake))
:config
(add-to-list 'eglot-server-programs '((c++-mode c-mode) "clangd")))Flycheck
Flycheck is the checking system for Emacs. I don't necessarily like having all my code checked all the time, so I haven't added a hook to prog-mode as it would be better for me to decide when I want checking and when I don't.
(use-package flycheck
:commands (flycheck-mode flycheck-list-errors)
:general
(leader
"tf" #'flycheck-mode
"cx" #'flycheck-list-errors)
:display
("\\*Flycheck.*"
(display-buffer-at-bottom)
(window-height . 0.25))
:config
(with-eval-after-load "evil-collection"
(evil-collection-flycheck-setup)))Tabs and spaces
By default, turn off tabs and set the tab width to two.
(setq-default indent-tabs-mode nil
tab-width 2)However, if necessary later, define a function that may activate tabs locally.
(defun dx:activate-tabs ()
(interactive)
(setq-local indent-tabs-mode t))Colourising compilation
Colourising the compilation buffer so ansi color codes get computed.
(use-package compile
:defer t
:straight nil
:config
(defun +compile/colourise ()
"Colourise the emacs compilation buffer."
(let ((inhibit-read-only t))
(ansi-color-apply-on-region (point-min) (point-max))))
(add-hook 'compilation-filter-hook #'+compile/colourise))Highlight todo items
TODO items are highlighted in org buffers, but not necessarily in every buffer. This minor mode highlights all TODO like items via a list of strings to match. It also configures faces to use when highlighting.
(use-package hl-todo
:after prog-mode
:hook (prog-mode-hook . hl-todo-mode)
:init
(setq hl-todo-keyword-faces
'(("TODO" . "#E50000")
("WAIT" . "#00CC00"))))PDFs are a great format for (somewhat) immutable text and reports with great formatting options. Though Emacs isn't really the premier solution for viewing PDFs (I highly recommend Zathura), similar to most things with Emacs, having a PDF viewer builtin can be a very useful asset.
For example if I were editing an org document which I was eventually compiling into a PDF, my workflow would be much smoother with a PDF viewer within Emacs that I can open on another pane.
Furthermore many governmental studies and essays use the PDF format. If I were to be analysing them in a study or project (for example, programming a tool using data from them), which I will most definitely be using Emacs for, having a PDF pane open for occasional viewing can be very useful.
PDF Tools
pdf-tools provides the necessary functionality for viewing
PDFs. There is no PDF viewing without this package. evil-collection
provides a setup for this mode, so use that.
(use-package pdf-tools
:mode ("\\.[pP][dD][fF]" . pdf-view-mode)
:config
(with-eval-after-load "evil-collection"
(evil-collection-pdf-setup)))PDF grep
PDF grep is a Linux tool that allows for searches against PDFs similar to standard grep (but for PDFs!). It's a bit badly configured (why not use the current buffer?) but it works out.
(use-package pdfgrep
:after pdf-tools
:hook (pdf-view-mode-hook . pdfgrep-mode)
:general
(general-def
:states 'normal
:keymaps 'pdf-view-mode-map
"M-g" #'pdfgrep))Ada
Check out ada-mode*, my custom ada-mode that replaces the default one. This mode just colourises stuff, and uses eglot to do the heavy lifting.
(load-file (concat user-emacs-directory "ada-mode.el"))
(with-eval-after-load "eglot"
(add-hook 'ada-mode-hook #'eglot))NHexl
Hexl-mode is the inbuilt package within Emacs to edit hex and binary format buffers. Though I doubt many programmers nowadays are wrangling with binary formats at such a precise level, I like to use binary formats in my programs sometimes. There are a few problems with hexl-mode though, including an annoying prompt on revert-buffer.
Thus, nhexl-mode! It comes with a few other improvements, but I care not to describe them. Check out the page yourself.
(use-package nhexl-mode
:straight t
:mode "\\.bin")Org
Org Core Variables
Tons of variables for org-mode, including a ton of latex ones.
(use-package org
:defer t
:custom
(org-agenda-files `(,(expand-file-name "~/Text/general.org")))
(org-agenda-window-setup 'current-window)
(org-edit-src-content-indentation 0)
(org-goto-interface 'outline)
(org-src-window-setup 'current-window)
(org-indirect-buffer-display 'current-window)
(org-eldoc-breadcrumb-separator " → ")
(org-enforce-todo-dependencies t)
(org-fontify-quote-and-verse-blocks t)
(org-fontify-whole-heading-line t)
(org-footnote-auto-label 'plain)
(org-hide-leading-stars t)
(org-hide-emphasis-markers nil)
(org-image-actual-width nil)
(org-priority-faces '((?A . error) (?B . warning) (?C . success)))
(org-startup-indented t)
(org-tags-column 0)
(org-todo-keywords
'((sequence "TODO" "WAIT" "DONE")
(sequence "PROJ" "WAIT" "COMPLETE")))
(org-use-sub-superscripts '{})
(org-babel-load-languages '((emacs-lisp . t)
(C . t)
(python . t)))
(org-latex-listings 'minted)
(org-latex-minted-langs '((emacs-lisp "common-lisp")
(ledger "text")
(cc "c++")
(cperl "perl")
(shell-script "bash")
(caml "ocaml")))
(org-latex-packages-alist '(("" "minted")))
(org-latex-pdf-process
'("%latex -interaction nonstopmode -shell-escape -output-directory %o %f"
"%latex -interaction nonstopmode -shell-escape -output-directory %o %f"
"%latex -interaction nonstopmode -shell-escape -output-directory %o %f"))
(org-latex-minted-options '(("style" "xcode")
("linenos")
("frame" "single")
("mathescape")
("fontfamily" "courier")
("samepage" "false")
("breaklines" "true")
("breakanywhere" "true")
)))Org Core Configuration
Hooks, prettify-symbols and my +org/swiper-goto to replace the
vanilla org-goto. Also records for auto insertion.
(use-package org
:hook
(org-mode-hook . prettify-symbols-mode)
:display
("\\*Org Src.*"
(display-buffer-same-window))
:pretty
(org-mode-hook
("#+begin_src" . "≫")
("#+end_src" . "≪"))
:init
(with-eval-after-load "autoinsert"
(define-auto-insert '("\\.org\\'" . "Org skeleton")
'("Enter title: "
"#+title: " str | (buffer-file-name) "\n"
"#+author: " (read-string "Enter author: ") | user-full-name "\n"
"#+description: " (read-string "Enter description: ") | "Description" "\n"
"#+options: toc:nil\n\n"
"#+begin_center\n"
(read-string "Enter further preamble: ") "\n"
"#+end_center\n"
"#+latex: \clearpage\n"
"#+toc: headlines\n"
"#+latex: \clearpage\n\n"
"* " _)))
:config
(with-eval-after-load "swiper"
(defun +org/swiper-goto ()
(interactive)
(swiper "^\\* "))
(general-def
[remap org-goto] #'+org/swiper-goto)))Org Core Bindings
Some bindings for org mode.
(use-package org
:general
(leader
"aa" #'org-agenda
"fa" (proc (interactive) (find-file (car org-agenda-files))))
(general-def
:states '(normal motion)
:keymaps 'org-mode-map
"C-c ;" #'org-property-action))Org message
Org message allows for the use of org mode when composing mails, generating HTML multipart emails. This integrates the WYSIWYG experience into mail in Emacs while also providing powerful text features with basically no learning curve (as long as you've already learnt the basics of org).
(use-package org-msg
:hook (message-mode-hook . org-msg-mode)
:after message-mode
:config
(setq org-msg-options "html-postamble:nil H:5 num:nil ^:{} toc:nil author:nil email:nil \\n:t tex:dvipng"
org-msg-greeting-name-limit 3
org-msg-text-plain-alternative t)
(add-to-list 'org-msg-enforce-css
'(img latex-fragment-inline
((transform . ,(format "translateY(-1px) scale(%.3f)"
(/ 1.0 (if (boundp 'preview-scale)
preview-scale 1.4))))
(margin . "0 -0.35em")))))Evil Org
Evil org for some nice bindings.
(use-package evil-org
:hook (org-mode-hook . evil-org-mode))Org reveal
Org reveal allows one to export org files as HTML presentations via reveal.js. Pretty nifty and it's easy to use.
(use-package ox-reveal
:after org
:init
(setq org-reveal-root "https://cdn.jsdelivr.net/npm/reveal.js"
org-reveal-theme "sky"))Org fragtog
Toggle latex fragments in org mode so you get fancy maths symbols. I use latex a bit in org mode as it is the premier way of getting mathematical symbols and text rendered and compiled, but org mode > latex.
As Org mode has the ability to accept arbitrary inputs of Latex (through escaped (square) brackets), allowing me to observe how they look is nice to have.
(use-package org-fragtog
:hook (org-mode-hook . org-fragtog-mode))Org pretty tables
Make the default ASCII tables of org mode pretty with
(use-package org-pretty-table
:straight (org-pretty-table-mode :type git :host github :repo "Fuco1/org-pretty-table")
:hook (org-mode-hook . org-pretty-table-mode))Org pretty tags
(use-package org-pretty-tags
:hook (org-mode-hook . org-pretty-tags-mode))Org superstar
Org superstar adds cute little unicode symbols for headers, much better than the default asterisks.
(use-package org-superstar
:hook (org-mode-hook . org-superstar-mode))C/C++
Setup for C and C++ modes via the cc-mode package. C and C++ are great languages for general purpose programming. Though lisp is more aesthetically and mentally pleasing, they get the job done. Furthermore, they provide speed and finer control in trade of aesthetics and security-based abstractions.
When writing C/C++ code, I use folds and section manipulation quite a bit so observing folds is quite important for me when considering a codebase. Thus, I observed the two main styles of brace placement and how they do folds.
if (cond) {...}vs
if (cond)
{....}I don't print my code, nor am I absolutely pressed for screen real estate in terms of height (such that newlines matter). Width matters to me as I do use Emacs multiplexing capabilities often. Thus, with these in mind the open brace style is a better option than the opposing style.
Configuration
(use-package cc-mode
:defer t
:hook
(c-mode-hook . auto-fill-mode)
(c++-mode-hook . auto-fill-mode)
:pretty
(c-mode-hook
("puts" . "ℙ")
("fputs" . "ϕ")
("printf" . "ω")
("fprintf" . "Ω")
("->" . "→")
("NULL" . "∅")
("true" . "⊤")
("false" . "⊥")
("char" . "ℂ")
("int" . "ℤ")
("float" . "ℝ")
("!" . "¬")
("&&" . "∧")
("||" . "∨")
("for" . "∀")
("return" . "⟼"))
(c++-mode-hook
("nullptr" . "∅")
("string" . "𝕊")
("string" . "𝕊")
("vector" . "ℓ")
("puts" . "ℙ")
("fputs" . "ϕ")
("printf" . "ω")
("fprintf" . "Ω")
("->" . "→")
("NULL" . "∅")
("true" . "⊤")
("false" . "⊥")
("char" . "ℂ")
("int" . "ℤ")
("float" . "ℝ")
("!" . "¬")
("&&" . "∧")
("||" . "∨")
("for" . "∀")
("return" . "⟼"))
:init
(setq-default c-basic-offset 2)
(setq-default c-default-style '((other . "user")))
(with-eval-after-load "autoinsert"
(define-auto-insert
'("\\.c\\'" . "C skeleton")
'(""
"/* " (file-name-nondirectory (buffer-file-name (current-buffer))) "\n"
" * Date: " (format-time-string "%Y-%m-%d") "\n"
" * Author: " user-full-name "\n"
" */\n"
"\n"
"\n"
_))
(define-auto-insert
'("\\.cpp\\'" . "C++ skeleton")
'(""
"/* " (file-name-nondirectory (buffer-file-name (current-buffer))) "\n"
" * Date: " (format-time-string "%Y-%m-%d") "\n"
" * Author: " user-full-name "\n"
" */\n"
"\n"
"\n"
_)))
:config
(with-eval-after-load "abbrev"
(+autotyping/gen-skeleton-abbrev
c-mode
"sgen"
"Name of item: "
str | "name" "\n"
"{\n"
> _ "\n"
"}\n")
(+autotyping/gen-skeleton-abbrev
c++-mode
"sgen"
"Name of item: "
> str | "name" "\n"
"{\n"
> _ "\n"
"}\n"))
(c-add-style
"user"
'((c-basic-offset . 2)
(c-comment-only-line-offset . 0)
(c-hanging-braces-alist (brace-list-open)
(brace-entry-open)
(substatement-open after)
(block-close . c-snug-do-while)
(arglist-cont-nonempty))
(c-cleanup-list brace-else-brace)
(c-offsets-alist
(statement-block-intro . +)
(substatement-open . 0)
(access-label . -)
(inline-open . 0)
(label . 0)
(statement-cont . +)))))Clang format
Clang format comes in built with clang, so download that before using this.
(use-package clang-format
:load-path "/usr/share/clang/"
:after cc-mode
:commands +code/clang-format-region-or-buffer
:general
(leader
:keymaps '(c-mode-map c++-mode-map)
"cf" #'+code/clang-format-region-or-buffer)
:config
(defun +code/clang-format-region-or-buffer ()
(interactive)
(if (mark)
(clang-format-region)
(clang-format-buffer))))Java
(use-package ob-java
:straight nil
:pretty
(java-mode-hook
("println" . "ℙ")
("printf" . "ω")
("null" . "∅")
("true" . "⊤")
("false" . "⊥")
("char" . "ℂ")
("int" . "ℤ")
("float" . "ℝ")
("!" . "¬")
("&&" . "∧")
("||" . "∨")
("for" . "∀")
("return" . "⟼"))
:config
(with-eval-after-load "cc-mode"
(c-add-style
"java"
'((c-basic-offset . 4)
(c-comment-only-line-offset 0 . 0)
(c-offsets-alist
(inline-open . 0)
(topmost-intro-cont . +)
(statement-block-intro . +)
(knr-argdecl-intro . 5)
(substatement-open . 0)
(substatement-label . +)
(label . +)
(statement-case-open . +)
(statement-cont . +)
(arglist-intro . c-lineup-arglist-intro-after-paren)
(arglist-close . c-lineup-arglist)
(brace-list-intro first c-lineup-2nd-brace-entry-in-arglist c-lineup-class-decl-init-+ +)
(access-label . 0)
(inher-cont . c-lineup-java-inher)
(func-decl-cont . c-lineup-java-throws))))
(add-to-list 'c-default-style '(java-mode . "java")))
(with-eval-after-load "abbrev"
(define-abbrev-table 'java-mode-abbrev-table nil)
(add-hook 'java-mode-hook
(proc (setq-local local-abbrev-table java-mode-abbrev-table)))
(+autotyping/gen-skeleton-abbrev
java-mode
"sgen"
"Name of item: "
str | "name" " {\n"
> _ "\n"
"}\n")))Haskell
Haskell is a static lazy functional programming language (what a mouthful). It's quite a beautiful language and really learning it will change the way you think about programming.
Here I configure the REPL for Haskell via the
interactive-haskell-mode as well.
(use-package haskell-mode
:hook
(haskell-mode-hook . haskell-indentation-mode)
(haskell-mode-hook . interactive-haskell-mode)
:general
(leader
"th" #'+shell/toggle-haskell-repl)
:display
("\\*haskell\\*"
(display-buffer-at-bottom)
(window-height . 0.25))
:config
(+dx/create-toggle-function
+shell/toggle-haskell-repl
"*haskell*"
haskell-process-restart))Python
Basic, haven't used python in this configuration yet.
(use-package python
:defer t
:straight nil
:pretty
(python-mode-hook
("None" . "∅")
("list" . "ℓ")
("List" . "ℓ")
("str" . "𝕊")
("True" . "⊤")
("False" . "⊥")
("int" . "ℤ")
("float" . "ℝ")
("not" . "¬")
("and" . "∧")
("or" . "∨")
("for" . "∀")
("print" . "ℙ")
("lambda" . "λ")
("return" . "⟼")
("yield" . "⟻"))
:init
(setq python-indent-offset 4))Python shell
Setup for python shell, including a toggle option
(use-package python
:straight nil
:commands +python/toggle-repl
:general
(leader
"tp" #'+python/toggle-repl)
:display
("\\*Python\\*"
(display-buffer-at-bottom)
(window-height . 0.25))
:config
(+dx/create-toggle-function +python/toggle-repl
"*Python*"
run-python))YAML
YAML is a data language which is useful for config files.
(use-package yaml-mode
:straight t)HTML/CSS/JS
Firstly, web mode for consistent colouring of syntax.
(use-package web-mode
:mode ("\\.html" . web-mode)
:mode ("\\.js" . web-mode)
:mode ("\\.css" . web-mode)
:custom
((web-mode-code-indent-offset 2)
(web-mode-markup-indent-offset 2)
(web-mode-css-indent-offset 2)))Then emmet for super speed
(use-package emmet-mode
:hook (web-mode-hook . emmet-mode)
:general
(general-def
:states 'insert
:keymaps 'emmet-mode-keymap
"TAB" #'emmet-expand-line
"M-j" #'emmet-next-edit-point
"M-k" #'emmet-prev-edit-point))Emacs lisp
Add a new lisp indent function which indents newline lists more appropriately.
(use-package lisp-mode
:straight nil
:pretty
(emacs-lisp-mode-hook
("lambda" . "λ")
("numberp" . "ℤ")
("t" . "𝕋")
("nil" . "∅")
("and" . "∧")
("or" . "∨")
("defun" . "ƒ")
("for" . "∀")
("mapc" . "∀")
("mapcar" . "∀"))
:config
(defun +modded/lisp-indent-function (indent-point state)
(let ((normal-indent (current-column))
(orig-point (point)))
(goto-char (1+ (elt state 1)))
(parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
(cond
;; car of form doesn't seem to be a symbol, or is a keyword
((and (elt state 2)
(or (not (looking-at "\\sw\\|\\s_"))
(looking-at ":")))
(if (not (> (save-excursion (forward-line 1) (point))
calculate-lisp-indent-last-sexp))
(progn (goto-char calculate-lisp-indent-last-sexp)
(beginning-of-line)
(parse-partial-sexp (point)
calculate-lisp-indent-last-sexp 0 t)))
;; Indent under the list or under the first sexp on the same
;; line as calculate-lisp-indent-last-sexp. Note that first
;; thing on that line has to be complete sexp since we are
;; inside the innermost containing sexp.
(backward-prefix-chars)
(current-column))
((and (save-excursion
(goto-char indent-point)
(skip-syntax-forward " ")
(not (looking-at ":")))
(save-excursion
(goto-char orig-point)
(looking-at ":")))
(save-excursion
(goto-char (+ 2 (elt state 1)))
(current-column)))
(t
(let ((function (buffer-substring (point)
(progn (forward-sexp 1) (point))))
method)
(setq method (or (function-get (intern-soft function)
'lisp-indent-function)
(get (intern-soft function) 'lisp-indent-hook)))
(cond ((or (eq method 'defun)
(and (null method)
(> (length function) 3)
(string-match "\\`def" function)))
(lisp-indent-defform state indent-point))
((integerp method)
(lisp-indent-specform method state
indent-point normal-indent))
(method
(funcall method indent-point state))))))))
(add-hook 'emacs-lisp-mode-hook (proc (interactive) (setq-local lisp-indent-function #'+modded/lisp-indent-function))))